it-swarm-vi.com

Làm cách nào để có được datetime hiện tại trên dòng lệnh Windows, ở định dạng phù hợp để sử dụng trong tên tệp?

Cập nhật: Bây giờ là năm 2016 tôi sẽ sử dụng PowerShell cho điều này trừ khi có lý do thực sự tương thích ngược với nó, đặc biệt là do vấn đề cài đặt khu vực khi sử dụng date. Xem @ npocmaka's https://stackoverflow.com/a/19799236/8479


Tôi có thể sử dụng câu lệnh dòng Windows nào để lấy datetime hiện tại theo định dạng mà tôi có thể đặt vào tên tệp?

Tôi muốn có một tệp .bat nén thư mục vào một kho lưu trữ với ngày và giờ hiện tại như một phần của tên, ví dụ: Code_2008-10-14_2257.Zip. Có cách nào dễ dàng để tôi có thể làm điều này, độc lập với cài đặt khu vực của máy không?

Tôi không thực sự bận tâm về định dạng ngày tháng, lý tưởng nhất là yyyy-mm-dd, nhưng mọi thứ đơn giản đều ổn.

Cho đến nay tôi đã có cái này, cái mà trên máy của tôi mang lại cho tôi Tue_10_14_2008_230050_91:

rem Get the datetime in a format that can go in a filename.
set _my_datetime=%date%_%time%
set _my_datetime=%_my_datetime: =_%
set _my_datetime=%_my_datetime::=%
set _my_datetime=%_my_datetime:/=_%
set _my_datetime=%_my_datetime:.=_%

rem Now use the timestamp by in a new Zip file name.
"d:\Program Files\7-Zip\7z.exe" a -r Code_%_my_datetime%.Zip Code

Tôi có thể sống với điều này, nhưng nó có vẻ hơi lộn xộn. Lý tưởng nhất là nó dễ hiểu hơn và có định dạng được đề cập trước đó.

Tôi đang sử dụng Windows Server 2003 và Windows XP Professional. Tôi không muốn cài đặt các tiện ích bổ sung để đạt được điều này (mặc dù tôi nhận thấy có một số tiện ích sẽ thực hiện định dạng ngày đẹp).

498
Rory

XemWindows Batch File (.bat) để có được ngày hiện tại ở định dạng MMDDYYYY:

@echo off
For /f "tokens=2-4 delims=/ " %%a in ('date /t') do (set mydate=%%c-%%a-%%b)
For /f "tokens=1-2 delims=/:" %%a in ('time /t') do (set mytime=%%a%%b)
echo %mydate%_%mytime%

Nếu bạn thích thời gian ở định dạng 24 giờ/quân đội, bạn có thể thay thế dòng FOR thứ hai bằng dòng này:

For /f "tokens=1-2 delims=/:" %%a in ("%TIME%") do (set mytime=%%a%%b)

C:>.\Date.bat
[.__.] 2008-10-14_0642

Nếu bạn muốn ngày độc lập với thứ tự ngày/tháng của khu vực, bạn có thể sử dụng "WMIC os GET LocalDateTime" làm nguồn, vì nó theo thứ tự ISO:

@echo off
for /F "usebackq tokens=1,2 delims==" %%i in (`wmic os get LocalDateTime /VALUE 2^>NUL`) do if '.%%i.'=='.LocalDateTime.' set ldt=%%j
set ldt=%ldt:~0,4%-%ldt:~4,2%-%ldt:~6,2% %ldt:~8,2%:%ldt:~10,2%:%ldt:~12,6%
echo Local date is [%ldt%]

C:> test.cmd
[.__.] Ngày địa phương là [2012-06-19 10: 23: 47.048]

637
Jay

Phân tích thời gian ngày độc lập theo vùng

Định dạng đầu ra của %DATE% và của lệnh dir phụ thuộc vào khu vực và do đó không mạnh mẽ cũng không thông minh. date.exe (một phần của UnxUtils ) cung cấp bất kỳ thông tin ngày và giờ ở bất kỳ định dạng có thể nghĩ được. Bạn cũng có thể trích xuất thông tin ngày/giờ từ bất kỳ tệp nào có date.exe.

Ví dụ: (trong tập lệnh cmd sử dụng %% thay vì%)

date.exe +"%Y-%m-%d"
[.__.] 2009-12-22

date.exe +"%T"
[.__.] 18:55:03

date.exe +"%Y%m%d %H%M%S: Any text"
[.__.] 20091222 185503: Bất kỳ văn bản nào

date.exe +"Text: %y/%m/%d-any text-%H.%M"
[.__.] Văn bản: 09/12/12 - bất kỳ văn bản nào - 18.55

Command: date.exe +"%m-%d """%H %M %S """"
[.__.] 07-22 "18:55:03" `

Thông tin ngày/giờ từ tệp tham chiếu:
[.__.] date.exe -r c:\file.txt +"The timestamp of file.txt is: %Y-%m-%d %H:%M:%S"

Sử dụng nó trong tập lệnh CMD để lấy thông tin năm, tháng, ngày, thời gian:

for /f "tokens=1,2,3,4,5,6* delims=," %%i in ('C:\Tools\etc\date.exe +"%%y,%%m,%%d,%%H,%%M,%%S"') do set yy=%%i& set mo=%%j& set dd=%%k& set hh=%%l& set mm=%%m& set ss=%%n

Sử dụng nó trong tập lệnh CMD để lấy dấu thời gian ở bất kỳ định dạng bắt buộc nào:

for /f "tokens=*" %%i in ('C:\Tools\etc\date.exe +"%%y-%%m-%%d %%H:%%M:%%S"') do set timestamp=%%i

Trích xuất thông tin ngày/giờ từ bất kỳ tập tin tham khảo.

for /f "tokens=1,2,3,4,5,6* delims=," %%i in ('C:\Tools\etc\date.exe -r file.txt +"%%y,%%m,%%d,%%H,%%M,%%S"') do set yy=%%i& set mo=%%j& set dd=%%k& set hh=%%l& set mm=%%m& set ss=%%n

Thêm vào một tập tin thông tin ngày/giờ của nó:

for /f "tokens=*" %%i in ('C:\Tools\etc\date.exe -r file.txt +"%%y-%%m-%%d.%%H%%M%%S"') do ren file.txt file.%%i.txt

date.exe là một phần của các công cụ GNU miễn phí không cần cài đặt.

LƯU Ý: Sao chép date.exe vào bất kỳ thư mục nào trong đường dẫn tìm kiếm có thể khiến các tập lệnh khác không sử dụng lệnh date tích hợp trong Windows.

100
Uri Liebeskind

Hai cách nữa không phụ thuộc vào cài đặt thời gian (cả hai được lấy từ : Làm thế nào để dữ liệu/thời gian độc lập với nội địa hóa: ). Và cả hai cũng có được ngày trong tuần và không ai trong số họ yêu cầu quyền quản trị!:

  1. MAKECAB- sẽ hoạt động trên MỌI hệ thống Windows (nhanh, nhưng tạo một tệp tạm thời nhỏ) (tập lệnh foxidrive):

    @echo off
    pushd "%temp%"
    makecab /D RptFileName=~.rpt /D InfFileName=~.inf /f nul >nul
    for /f "tokens=3-7" %%a in ('find /i "makecab"^<~.rpt') do (
       set "current-date=%%e-%%b-%%c"
       set "current-time=%%d"
       set "weekday=%%a"
    )
    del ~.*
    popd
    echo %weekday% %current-date% %current-time%
    pause
    

    Thông tin thêm về chức năng nhận ngày .

  2. ROBOCOPY- đó không phải là lệnh gốc cho Windows XP và Windows Server 2003, nhưng nó có thể được tải xuống từ trang web của Microsoft . Nhưng được tích hợp sẵn mọi thứ từ Windows Vista trở lên:

    @echo off
    setlocal
    for /f "skip=8 tokens=2,3,4,5,6,7,8 delims=: " %%D in ('robocopy /l * \ \ /ns /nc /ndl /nfl /np /njh /XF * /XD *') do (
     set "dow=%%D"
     set "month=%%E"
     set "day=%%F"
     set "HH=%%G"
     set "MM=%%H"
     set "SS=%%I"
     set "year=%%J"
    )
    
    echo Day of the week: %dow%
    echo Day of the month : %day%
    echo Month : %month%
    echo hour : %HH%
    echo minutes : %MM%
    echo seconds : %SS%
    echo year : %year%
    endlocal
    

    Và ba cách nữa sử dụng các ngôn ngữ script Windows khác. Họ sẽ cho bạn linh hoạt hơn, ví dụ: bạn có thể nhận được tuần trong năm, thời gian tính bằng mili giây và cứ thế.

  3. JScript/batch hybrid (cần được lưu dưới dạng .bat). JScript có sẵn trên mọi mẫu hệ thống NT trở lên, như là một phần của Windows Script Host ( mặc dù có thể bị vô hiệu hóa thông qua sổ đăng ký, đây là trường hợp hiếm gặp ):

    @if (@X)==(@Y) @end /* ---Harmless hybrid line that begins a JScript comment
    
    @echo off
    cscript //E:JScript //nologo "%~f0"
    exit /b 0
    *------------------------------------------------------------------------------*/
    
    function GetCurrentDate() {
            // Today date time which will used to set as default date.
            var todayDate = new Date();
            todayDate = todayDate.getFullYear() + "-" +
                           ("0" + (todayDate.getMonth() + 1)).slice(-2) + "-" +
                           ("0" + todayDate.getDate()).slice(-2) + " " + ("0" + todayDate.getHours()).slice(-2) + ":" +
                           ("0" + todayDate.getMinutes()).slice(-2);
    
            return todayDate;
        }
    
    WScript.Echo(GetCurrentDate());
    
  4. VSCRIPT/BATCH hybrid (Có thể nhúng và thực thi VBScript trong một tệp bó mà không sử dụng tệp tạm thời không?) giống như trường hợp JScript hoàn hảo:

    :sub echo(str) :end sub
    echo off
    '>nul 2>&1|| copy /Y %windir%\System32\doskey.exe %windir%\System32\'.exe >nul
    '& echo current date:
    '& cscript /nologo /E:vbscript "%~f0"
    '& exit /b
    
    '0 = vbGeneralDate - Default. Returns date: mm/dd/yy and time if specified: hh:mm:ss PM/AM.
    '1 = vbLongDate - Returns date: weekday, monthname, year
    '2 = vbShortDate - Returns date: mm/dd/yy
    '3 = vbLongTime - Returns time: hh:mm:ss PM/AM
    '4 = vbShortTime - Return time: hh:mm
    
    WScript.echo  Replace(FormatDateTime(Date,1),", ","-")
    
  5. PowerShell - có thể được cài đặt trên mọi máy có .NET - tải xuống từ Microsoft ( v1 , v2 , v3 (chỉ dành cho Windows 7 trở lên)). Nó được cài đặt theo mặc định trên mọi thứ từ Windows 7/Windows Server 2008 trở lên:

    C:\> powershell get-date -format "{dd-MMM-yyyy HH:mm}"
    

    Để sử dụng nó từ một tệp bó:

    for /f "delims=" %%# in ('powershell get-date -format "{dd-MMM-yyyy HH:mm}"') do @set _date=%%#
    
  6. jscript.net/batch tự biên dịch (chưa bao giờ thấy máy Windows không có .NET, vì vậy tôi nghĩ đây là một thiết bị di động khá đẹp):

    @if (@X)==(@Y) @end /****** silent line that start JScript comment ******
    
    @echo off
    ::::::::::::::::::::::::::::::::::::
    :::       Compile the script    ::::
    ::::::::::::::::::::::::::::::::::::
    setlocal
    if exist "%~n0.exe" goto :skip_compilation
    
    set "frm=%SystemRoot%\Microsoft.NET\Framework\"
    
    :: Searching the latest installed .NET framework
    for /f "tokens=* delims=" %%v in ('dir /b /s /a:d /o:-n "%SystemRoot%\Microsoft.NET\Framework\v*"') do (
        if exist "%%v\jsc.exe" (
            rem :: the javascript.net compiler
            set "jsc=%%~dpsnfxv\jsc.exe"
            goto :break_loop
        )
    )
    echo jsc.exe not found && exit /b 0
    :break_loop
    
    
    call %jsc% /nologo /out:"%~n0.exe" "%~dpsfnx0"
    ::::::::::::::::::::::::::::::::::::
    :::       End of compilation    ::::
    ::::::::::::::::::::::::::::::::::::
    :skip_compilation
    
    "%~n0.exe"
    
    exit /b 0
    
    
    ****** End of JScript comment ******/
    import System;
    import System.IO;
    
    var dt=DateTime.Now;
    Console.WriteLine(dt.ToString("yyyy-MM-dd hh:mm:ss"));
    
  7. Logman Điều này không thể có được năm và ngày trong tuần. Nó tương đối chậm và cũng tạo ra một tệp tạm thời và dựa trên dấu thời gian mà logman đặt trên các tệp nhật ký của nó. Nó sẽ hoạt động trên mọi thứ từ Windows XP trở lên. Nó có thể sẽ không bao giờ được sử dụng bởi bất kỳ ai - kể cả tôi - nhưng là một cách khác ...

    @echo off
    setlocal
    del /q /f %temp%\timestampfile_*
    
    Logman.exe stop ts-CPU 1>nul 2>&1
    Logman.exe delete ts-CPU 1>nul 2>&1
    
    Logman.exe create counter ts-CPU  -sc 2 -v mmddhhmm -max 250 -c "\Processor(_Total)\%% Processor Time" -o %temp%\timestampfile_ >nul
    Logman.exe start ts-CPU 1>nul 2>&1
    
    Logman.exe stop ts-CPU >nul 2>&1
    Logman.exe delete ts-CPU >nul 2>&1
    for /f "tokens=2 delims=_." %%t in  ('dir /b %temp%\timestampfile_*^&del /q/f %temp%\timestampfile_*') do set timestamp=%%t
    
    echo %timestamp%
    echo MM: %timestamp:~0,2%
    echo dd: %timestamp:~2,2%
    echo hh: %timestamp:~4,2%
    echo mm: %timestamp:~6,2%
    
    endlocal
    exit /b 0
    
  8. Một cách nữa vớiWMICcũng cung cấp tuần trong năm và ngày trong tuần, nhưng không phải là mili giây (đối với mili giây kiểm tra câu trả lời của foxidrive):

    for /f %%# in ('wMIC Path Win32_LocalTime Get /Format:value') do @for /f %%@ in ("%%#") do @set %%@
    echo %day%
    echo %DayOfWeek%
    echo %hour%
    echo %minute%
    echo %month%
    echo %quarter%
    echo %second%
    echo %weekinmonth%
    echo %year%
    
  9. Sử dụngTYPEPERFvới một số nỗ lực để nhanh chóng và tương thích với các cài đặt ngôn ngữ khác nhau và nhanh nhất có thể:

    @echo off
    setlocal
    
    :: Check if Windows is Windows XP and use Windows XP valid counter for UDP performance
    ::if defined USERDOMAIN_roamingprofile (set "v=v4") else (set "v=")
    
    for /f "tokens=4 delims=. " %%# in ('ver') do if %%# GTR 5 (set "v=v4") else ("v=")
    set "mon="
    for /f "skip=2 delims=," %%# in ('typeperf "\UDP%v%\*" -si 0 -sc 1') do (
       if not defined mon (
          for /f "tokens=1-7 delims=.:/ " %%a in (%%#) do (
            set mon=%%a
            set date=%%b
            set year=%%c
            set hour=%%d
            set minute=%%e
            set sec=%%f
            set ms=%%g
          )
       )
    )
    echo %year%.%mon%.%date%
    echo %hour%:%minute%:%sec%.%ms%
    endlocal
    
  10. MSHTAcho phép gọi các phương thức JavaScript tương tự như phương thức JScript được trình bày trong # 3 ở trên. Hãy nhớ rằng các thuộc tính đối tượng Ngày của JavaScript liên quan đến các giá trị tháng được đánh số từ 0 đến 11, không phải từ 1 đến 12. Vì vậy, giá trị 9 có nghĩa là tháng 10.

    <!-- : Batch portion
    
    @echo off
    setlocal
    
    for /f "delims=" %%I in ('mshta "%~f0"') do set "now.%%~I"
    
    rem Display all variables beginning with "now."
    set now.
    
    goto :EOF
    
    end batch / begin HTA -->
    
    <script>
        resizeTo(0,0)
        var fso = new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1),
            now = new Date(),
            props=['getDate','getDay','getFullYear','getHours','getMilliseconds','getMinutes',
                'getMonth','getSeconds','getTime','getTimezoneOffset','getUTCDate','getUTCDay',
                'getUTCFullYear','getUTCHours','getUTCMilliseconds','getUTCMinutes','getUTCMonth',
                'getUTCSeconds','getYear','toDateString','toGMTString','toLocaleDateString',
                'toLocaleTimeString','toString','toTimeString','toUTCString','valueOf'],
            output = [];
    
        for (var i in props) {output.Push(props[i] + '()=' + now[props[i]]())}
        close(fso.Write(output.join('\n')));
    </script>
    
86
npocmaka

Đây là một biến thể từ alt.msdos.batch.nt hoạt động độc lập cục bộ.

Đặt cái này trong một tệp văn bản, ví dụ: getDate.cmd

-----------8<------8<------------ snip -- snip ----------8<-------------
    :: Works on any NT/2k machine independent of regional date settings
    @ECHO off
    SETLOCAL ENABLEEXTENSIONS
    if "%date%A" LSS "A" (set toks=1-3) else (set toks=2-4)
    for /f "tokens=2-4 delims=(-)" %%a in ('echo:^|date') do (
      for /f "tokens=%toks% delims=.-/ " %%i in ('date/t') do (
        set '%%a'=%%i
        set '%%b'=%%j
        set '%%c'=%%k))
    if %'yy'% LSS 100 set 'yy'=20%'yy'%
    set Today=%'yy'%-%'mm'%-%'dd'% 
    ENDLOCAL & SET v_year=%'yy'%& SET v_month=%'mm'%& SET v_day=%'dd'%

    ECHO Today is Year: [%V_Year%] Month: [%V_Month%] Day: [%V_Day%]

    :EOF
-----------8<------8<------------ snip -- snip ----------8<-------------

Để có được mã hoạt động sans lỗi thông báo lỗi cho stderr, tôi đã phải thêm các trích dẫn duy nhất gợi lên các phép gán biến cho %% a, %% b và %% c. Ngôn ngữ của tôi (PT) đã gây ra lỗi ở một giai đoạn trong vòng lặp/phân tích cú pháp trong đó các công cụ như "set = 20" đang được thực thi. Các trích dẫn mang lại một mã thông báo (mặc dù trống) cho phía bên trái của câu lệnh gán.

Nhược điểm là tên biến địa phương lộn xộn: 'yy', 'mm' và 'dd'. Nhưng này, ai quan tâm chứ!

42
vMax

Tôi sử dụng cái này (một lần nữa không độc lập với khu vực (Anh))

set bklog=%date:~6,4%-%date:~3,2%-%date:~0,2%_%time:~0,2%%time:~3,2%
33
Dale Walker

Thật không may, điều này không tránh khỏi các thiết lập khu vực, nhưng nó làm những gì bạn muốn.

set hour=%time:~0,2%
if "%time:~0,1%"==" " set hour=0%time:~1,1%
set _my_datetime=%date:~10,4%-%date:~4,2%-%date:~7,2%_%hour%%time:~3,2%

Tuyệt vời những thứ bạn có thể tìm thấy trên Wikipedia .

24
Mark Ransom

Vui lòng sử dụng tập lệnh sau để có được ngày hiện tại trong dòng lệnh:

echo %Date:~0,3%day
16
sudipto roy

Bốn dòng đầu tiên của mã này sẽ cung cấp cho bạn các biến YY DD MM YYYY HH Min Sec đáng tin cậy trong Windows XP Professional trở lên.

@echo off
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"

set "datestamp=%YYYY%%MM%%DD%" & set "timestamp=%HH%%Min%%Sec%" & set "fullstamp=%YYYY%-%MM%-%DD%_%HH%%Min%-%Sec%"
echo datestamp: "%datestamp%"
echo timestamp: "%timestamp%"
echo fullstamp: "%fullstamp%"
pause
16
foxidrive

Một cách khác ( tín dụng ):

@For /F "tokens=2,3,4 delims=/ " %%A in ('Date /t') do @( 
    Set Month=%%A
    Set Day=%%B
    Set Year=%%C
)

@echo DAY = %Day%
@echo Month = %Month%
@echo Year = %Year%

Lưu ý rằng cả hai câu trả lời của tôi ở đây vẫn phụ thuộc vào thứ tự trong ngày và tháng được xác định bởi cài đặt khu vực - không chắc chắn cách xử lý xung quanh đó.

15
J c
"d:\Program Files\7-Zip\7z.exe" a -r code_%date:~10,4%-%date:~4,2%-%date:~7,2%.Zip
14
DigiP

Điều này không thực sự tốt hơn nhưng có thể là một cách linh hoạt hơn ( tín dụng ):

FOR /F "TOKENS=1* DELIMS= " %%A IN ('DATE/T') DO SET CDATE=%%B
FOR /F "TOKENS=1,2 eol=/ DELIMS=/ " %%A IN ('DATE/T') DO SET mm=%%B
FOR /F "TOKENS=1,2 DELIMS=/ eol=/" %%A IN ('echo %CDATE%') DO SET dd=%%B
FOR /F "TOKENS=2,3 DELIMS=/ " %%A IN ('echo %CDATE%') DO SET yyyy=%%B
SET date=%mm%%dd%%yyyy%
13
J c

Đây là một cách để có được thời gian ngày trong một dòng:

for /f "tokens=2,3,4,5,6 usebackq delims=:/ " %a in ('%date% %time%') do echo %c-%a-%b %d%e

Ở Mỹ, điều này sẽ tạo ra "yyyy-mm-dd hhmm". Các cài đặt khu vực khác nhau sẽ dẫn đến kết quả% ngày% khác nhau, nhưng bạn có thể sửa đổi thứ tự mã thông báo.

Nếu bạn muốn một định dạng khác, hãy sửa đổi câu lệnh echo bằng cách sắp xếp lại các mã thông báo hoặc sử dụng các dấu phân cách (hoặc không) khác nhau.

9
Matthew Johnson

Chỉ cần sử dụng dòng này:

PowerShell -Command "get-date"
8
gdelfino

Câu trả lời ngắn :

 :: Start - Run , type:
 cmd /c "powershell get-date -format ^"{yyyy-MM-dd HH:mm:ss}^"|clip"

 :: click into target media, Ctrl + V to paste the result 

Câu trả lời dài

    @echo off
    :: START USAGE  ==================================================================
    ::SET THE NICETIME 
    :: SET NICETIME=BOO
    :: CALL GetNiceTime.cmd 

    :: ECHO NICETIME IS %NICETIME%

    :: echo Nice time is %NICETIME%
    :: END USAGE  ==================================================================

    echo set hhmmsss
    :: this is Regional settings dependant so Tweak this according your current settings
    for /f "tokens=1-3 delims=:" %%a in ('echo %time%') do set hhmmsss=%%a%%b%%c 
    ::DEBUG ECHO hhmmsss IS %hhmmsss%
    ::DEBUG PAUSE
    echo %yyyymmdd%
        :: this is Regional settings dependant so Tweak this according your current settings
    for /f "tokens=1-3 delims=." %%D in ('echo %DATE%') do set  yyyymmdd=%%F%%E%%D
    ::DEBUG ECHO yyyymmdd IS %yyyymmdd%
    ::DEBUG PAUSE


    set NICETIME=%yyyymmdd%_%hhmmsss%
    ::DEBUG echo THE NICETIME IS %NICETIME%

    ::DEBUG PAUSE
8
Yordan Georgiev

Giải pháp của Matthew Johnson một lớp lót để có được ngày và thời gian một lớp lót là hùng hồn và hữu ích.

Tuy nhiên, nó cần một sửa đổi đơn giản để làm việc trong một tệp bó:

for /f "tokens=2,3,4,5,6 usebackq delims=:/ " %%a in ('%date% %time%') do echo %%c-%%a-%%b %%d%%e
7
John Langstaff

Và đây là một tệp bó tương tự cho phần thời gian.

:: http://stackoverflow.com/questions/203090/how-to-get-current-datetime-on-windows-command-line-in-a-suitable-format-for-usi
:: Works on any NT/2k machine independent of regional time settings
::
:: Gets the time in ISO 8601 24-hour format
::
:: Note that %time% gets you fractions of seconds, and time /t doesn't, but gets you AM/PM if your locale supports that.
:: Since ISO 8601 does not care about AM/PM, we use %time%
::
    @ECHO off
    SETLOCAL ENABLEEXTENSIONS
    for /f "tokens=1-4 delims=:,.-/ " %%i in ('echo %time%') do (
      set 'hh'=%%i
      set 'mm'=%%j
      set 'ss'=%%k
      set 'ff'=%%l)
    ENDLOCAL & SET v_Hour=%'hh'%& SET v_Minute=%'mm'%& SET v_Second=%'ss'%& SET v_Fraction=%'ff'%

    ECHO Now is Hour: [%V_Hour%] Minute: [%V_Minute%] Second: [%v_Second%] Fraction: [%v_Fraction%]
    set timestring=%V_Hour%%V_Minute%%v_Second%.%v_Fraction%
    echo %timestring%

    :EOF

--jeroen

7

Tôi đã thay đổi câu trả lời với tệp bó từ vMax để nó cũng hoạt động với ngôn ngữ Hà Lan.
[.__.] Người Hà Lan - kiên trì như chúng ta - có một vài thay đổi trong %date%, date/tdate phá vỡ tệp bó ban đầu.

Sẽ thật tuyệt nếu một số người cũng có thể kiểm tra điều này với các địa điểm Windows khác và báo cáo lại kết quả.
[.___.] Nếu tệp bó không thành công tại vị trí của bạn, thì vui lòng bao gồm đầu ra của hai câu lệnh này trên lệnh Nhắc:
[.__.] echo:^|date
[.__.] date/t

Đây là một mẫu đầu ra mà bạn sẽ nhận được từ tệp bó:

C:\temp>set-date-cmd.bat
Today is Year: [2011] Month: [01] Day: [03]
20110103

Dưới đây là mã sửa đổi với ý kiến ​​về lý do:

:: https://stackoverflow.com/questions/203090/how-to-get-current-datetime-on-windows-command-line-in-a-suitable-format-for-usi
:: Works on any NT/2k machine independent of regional date settings
::
:: 20110103 - adapted by [email protected] for Dutch locale
:: Dutch will get jj as year from echo:^|date, so the '%%c' trick does not work as it will fill 'jj', but we want 'yy'
:: luckily, all countries seem to have year at the end: http://en.wikipedia.org/wiki/Calendar_date
::            set '%%c'=%%k
::            set 'yy'=%%k
::
:: In addition, date will display the current date before the input Prompt using dashes
:: in Dutch, but using slashes in English, so there will be two occurances of the outer loop in Dutch
:: and one occurence in English.
:: This skips the first iteration:
::        if "%%a" GEQ "A"
::
:: echo:^|date
:: Huidige datum: ma 03-01-2011
:: Voer de nieuwe datum in: (dd-mm-jj)
:: The current date is: Mon 01/03/2011
:: Enter the new date: (mm-dd-yy)
::
:: date/t
:: ma 03-01-2011
:: Mon 01/03/2011
::
:: The assumption in this batch-file is that echo:^|date will return the date format
:: using either mm and dd or dd and mm in the first two valid tokens on the second line, and the year as the last token.
::
:: The outer loop will get the right tokens, the inner loop assigns the variables depending on the tokens.
:: That will resolve the order of the tokens.
::
@ECHO off
    set v_day=
    set v_month=
    set v_year=

    SETLOCAL ENABLEEXTENSIONS
    if "%date%A" LSS "A" (set toks=1-3) else (set toks=2-4)
::DEBUG echo toks=%toks%
      for /f "tokens=2-4 delims=(-)" %%a in ('echo:^|date') do (
::DEBUG echo first token=%%a
        if "%%a" GEQ "A" (
          for /f "tokens=%toks% delims=.-/ " %%i in ('date/t') do (
            set '%%a'=%%i
            set '%%b'=%%j
            set 'yy'=%%k
          )
        )
      )
      if %'yy'% LSS 100 set 'yy'=20%'yy'%
      set Today=%'yy'%-%'mm'%-%'dd'%

    ENDLOCAL & SET v_year=%'yy'%& SET v_month=%'mm'%& SET v_day=%'dd'%

    ECHO Today is Year: [%V_Year%] Month: [%V_Month%] Day: [%V_Day%]
    set datestring=%V_Year%%V_Month%%V_Day%
    echo %datestring%

    :EOF

--jeroen

7

Hàm dựa trên wmic:

:Now  -- Gets the current date and time into separate variables
::    %~1: [out] Year
::    %~2: [out] Month
::    %~3: [out] Day
::    %~4: [out] Hour
::    %~5: [out] Minute
::    %~6: [out] Second
  setlocal
  for /f %%t in ('wmic os get LocalDateTime ^| findstr /b [0-9]') do set T=%%t
  endlocal & (
    if "%~1" neq "" set %~1=%T:~0,4%
    if "%~2" neq "" set %~2=%T:~4,2%
    if "%~3" neq "" set %~3=%T:~6,2%
    if "%~4" neq "" set %~4=%T:~8,2%
    if "%~5" neq "" set %~5=%T:~10,2%
    if "%~6" neq "" set %~6=%T:~12,2%
  )
goto:eof

Ưu điểm: Vùng độc lập. Nhược điểm: Chỉ quản trị viên hệ thống mới có thể chạy wmic.exe.

Sử dụng:

call:Now Y M D H N S
echo %Y%-%M%-%D% %H%:%N%:%S%

Đây là một chuỗi như thế này:

2014-01-22 12:51:53

Lưu ý rằng các tham số chức năng là tham số ngoài - nghĩa là, bạn phải cung cấp tên biến thay vì giá trị.

Tất cả các tham số là tùy chọn, vì vậy call:Now Y M là một cuộc gọi hợp lệ nếu bạn chỉ muốn nhận năm và tháng.

6
Tomalak

Đây là những gì tôi đã sử dụng:

::Date Variables - replace characters that are not legal as part of filesystem file names (to produce name like "backup_04.15.08.7z")
SET DT=%date%
SET DT=%DT:/=.%
SET DT=%DT:-=.%

Nếu bạn muốn có thêm ý tưởng để tự động sao lưu vào kho lưu trữ 7-Zip, tôi có một dự án miễn phí/mở bạn có thể sử dụng hoặc xem xét cho các ý tưởng: http://wittman.org/ziparcy/

5
micahwittman

Tôi đã có một vấn đề tương tự. Tôi có tải xuống tự động hàng ngày từ máy chủ FTP của một tệp được mã hóa. Tôi muốn giải mã tệp bằng gpg, đổi tên tệp thành ngày hiện tại (định dạng YYYYMMDD) và thả tệp được giải mã vào một thư mục cho đúng bộ phận.

Tôi đã trải qua một số gợi ý để đổi tên tập tin theo ngày và không gặp may mắn cho đến khi tôi tình cờ tìm thấy giải pháp đơn giản này.

for /f "tokens=1-5 delims=/ " %%d in ("%date%") do rename "decrypted.txt" %%g-%%e-%%f.txt

Nó hoạt động hoàn hảo (nghĩa là, tên tệp xuất hiện là "2011-06-14.txt").

(Nguồn)

4
KChiki

http://sourceforge.net/projects/unxutils/files/

Nhìn vào bên trong tệp Zip để biết một cái gì đó gọi là "Date.exe" và đổi tên thành "DateFormat.exe" (để tránh xung đột).

Đặt nó trong thư mục Windows system32 của bạn.

Nó có rất nhiều tùy chọn "đầu ra ngày".

Để được trợ giúp, hãy sử dụng DateFormat.exe --h

Tôi không chắc chắn làm thế nào bạn sẽ đưa đầu ra của nó vào một biến môi trường ... bằng cách sử dụng SET.

4
Sally

Giải pháp độc lập khu vực tạo định dạng ngày ISO:

rem save the existing format definition
for /f "skip=2 tokens=3" %%a in ('reg query "HKCU\Control Panel\International" /v sShortDate') do set FORMAT=%%a
rem set ISO specific format definition
reg add "HKCU\Control Panel\International" /v sShortDate /t REG_SZ /f /d yyyy-MM-dd 1>nul:
rem query the date in the ISO specific format 
set ISODATE=%DATE%
rem restore previous format definition
reg add "HKCU\Control Panel\International" /v sShortDate /t REG_SZ /f /d %FORMAT% 1>nul:

Điều vẫn có thể được tối ưu hóa: Các quy trình khác có thể bị nhầm lẫn nếu sử dụng định dạng ngày trong khoảng thời gian ngắn trong khi nó được sửa đổi. Vì vậy, phân tích đầu ra theo chuỗi định dạng hiện tại có thể 'an toàn hơn' - nhưng sẽ phức tạp hơn

3
V15I0N
:: GetDate.cmd -> Uses WMIC.exe to get current date and time in ISO 8601 format
:: - Sets environment variables %_isotime% and %_now% to current time
:: - On failure, clears these environment variables
:: Inspired on -> https://ss64.com/nt/syntax-getdate.html
:: - (cX) 2017 [email protected]
:: - http://stackoverflow.com/questions/203090
@echo off

set _isotime=
set _now=

:: Check that WMIC.exe is available
WMIC.exe Alias /? >NUL 2>&1 || goto _WMIC_MISSING_

if not (%1)==() goto _help
SetLocal EnableDelayedExpansion

:: Use WMIC.exe to retrieve date and time
FOR /F "skip=1 tokens=1-6" %%G IN ('WMIC.exe Path Win32_LocalTime Get Day^,Hour^,Minute^,Month^,Second^,Year /Format:table') DO (
    IF "%%~L"=="" goto  _WMIC_done_
        set _yyyy=%%L
        set _mm=00%%J
        set _dd=00%%G
        set _hour=00%%H
        set _minute=00%%I
        set _second=00%%K
)
:_WMIC_done_

::   1    2     3       4      5      6
:: %%G  %%H    %%I     %%J    %%K    %%L
:: Day  Hour  Minute  Month  Second  Year
:: 27   9     35      4      38      2017

:: Remove excess leading zeroes
        set _mm=%_mm:~-2%
        set _dd=%_dd:~-2%
        set _hour=%_hour:~-2%
        set _minute=%_minute:~-2%
        set _second=%_second:~-2%
:: Syntax -> %variable:~num_chars_to_skip,num_chars_to_keep%

:: Set date/time in ISO 8601 format:
        Set _isotime=%_yyyy%-%_mm%-%_dd%T%_hour%:%_minute%:%_second%
:: -> http://google.com/search?num=100&q=ISO+8601+format

if 1%_hour% LSS 112 set _now=%_isotime:~0,10% %_hour%:%_minute%:%_second%am
if 1%_hour% LSS 112 goto _skip_12_
    set /a _hour=1%_hour%-12
    set _hour=%_hour:~-2%
    set _now=%_isotime:~0,10% %_hour%:%_minute%:%_second%pm
    :: -> https://ss64.com/nt/if.html
    :: -> http://google.com/search?num=100&q=SetLocal+EndLocal+Windows
    :: 'if () else ()' will NOT set %_now% correctly !?
:_skip_12_

EndLocal & set _isotime=%_isotime% & set _now=%_now%
goto _out

:_WMIC_MISSING_
echo.
echo WMIC.exe command not available
echo - WMIC.exe needs Administrator privileges to run in Windows
echo - Usually the path to WMIC.exe is "%windir%\System32\wbem\WMIC.exe"

:_help
echo.
echo GetDate.cmd: Uses WMIC.exe to get current date and time in ISO 8601 format
echo.
echo    %%_now%%     environment variable set to current date and time
echo    %%_isotime%% environment variable to current time in ISO format
echo    set _today=%%_isotime:~0,10%%
echo.

:_out
:: EOF: GetDate.cmd
2
Adolfo

Cho một địa phương được biết đến, để tham khảo ở dạng chức năng. Cuộc gọi ECHOTIMESTAMP chỉ ra cách lấy dấu thời gian thành một biến (DTS trong ví dụ này.)

@ECHO off

CALL :ECHOTIMESTAMP
GOTO END

:TIMESTAMP
SETLOCAL  EnableDelayedExpansion
    SET DATESTAMP=!DATE:~10,4!-!DATE:~4,2!-!DATE:~7,2!
    SET TIMESTAMP=!TIME:~0,2!-!TIME:~3,2!-!TIME:~6,2!
    SET DTS=!DATESTAMP: =0!-!TIMESTAMP: =0!
ENDLOCAL & SET "%~1=%DTS%"
GOTO :EOF

:ECHOTIMESTAMP
SETLOCAL
    CALL :TIMESTAMP DTS
    ECHO %DTS%
ENDLOCAL
GOTO :EOF

:END

EXIT /b 0

Và được lưu vào tệp, timestamp.bat, đây là đầu ra:

 enter image description here

0
bvj

Với Windows 7, mã này hoạt động với tôi:

SET DATE=%date%
SET YEAR=%DATE:~0,4%
SET MONTH=%DATE:~5,2%
SET DAY=%DATE:~8,2%
ECHO %YEAR%
ECHO %MONTH%
ECHO %DAY%

SET DATE_FRM=%YEAR%-%MONTH%-%DAY% 
ECHO %DATE_FRM%
0
Frizz1977

Tôi thích làm điều đó càng ngắn càng tốt, vì vậy không có tháng và năm là đủ để cập nhật hàng ngày

SET date=%DATE:~0,2%
SET hour=%TIME:~0,2%
SET minute=%TIME:~3,2%
IF "%date:~0,1%"==" " SET date=0%DATE:~1,1%
IF "%hour:~0,1%"==" " SET hour=0%TIME:~1,1%
IF "%minute:~0,1%"==" " SET minute=0%TIME:~1,1%
SET VERSION=%date%%hour%%minute%
ECHO VERSION=%date%%hour%%minute%
VERSION=140105

Khi nói đến phiên bản của một ứng dụng triển khai trong bản cập nhật mới hàng ngày với trình xây dựng

steps:
- name: "gcr.io/cloud-builders/gcloud"
  args: ["app", "deploy", '--version=v1-140105-fresh']
timeout: "300s"

Bằng cách này, việc tự động cập nhật toàn bộ ứng dụng sẽ dễ dàng hơn

sed -e "s/-[0-9]\{1,\}-fresh/-%VERSION%-local/g" cloudbuild.yaml > tmp.txt 
mv -f tmp.txt cloudbuild.yaml

Tệp đầu ra sẽ sẵn sàng để cập nhật cục bộ mà không cần chạm vào tên tệp của nó

steps:
- name: "gcr.io/cloud-builders/gcloud"
  args: ["app", "deploy", '--version=v1-140117-local']
timeout: "300s"
0
Chetabahana